gen_parser.m4 2.04 KB
Newer Older
1 2 3 4
m4_divert(-1)m4_dnl
#
#	BIRD -- Generator of Configuration Grammar
#
5
#	(c) 1998--1999 Martin Mares <mj@atrey.karlin.mff.cuni.cz>
6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21
#
#	Can be freely distributed and used under the terms of the GNU GPL.
#

# Diversions used:
#	1	includes
#	2	types etc.
#	3	rules
#	4	C code

# Common aliases
m4_define(DNL, `m4_dnl')

# Define macros for defining sections
m4_define(CF_ZONE, `m4_divert($1)/* $2 from m4___file__ */')
m4_define(CF_HDR, `CF_ZONE(1, Headers)')
22
m4_define(CF_DEFINES, `CF_ZONE(1, Defines)')
23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41
m4_define(CF_DECLS, `CF_ZONE(2, Declarations)')
m4_define(CF_GRAMMAR, `CF_ZONE(3, Grammar)')
m4_define(CF_CODE, `CF_ZONE(4, C Code)')
m4_define(CF_END, `m4_divert(-1)')

# Simple iterator
m4_define(CF_itera, `m4_ifelse($#, 1, [[CF_iter($1)]], [[CF_iter($1)[[]]CF_itera(m4_shift($@))]])')
m4_define(CF_iterate, `m4_define([[CF_iter]], m4_defn([[$1]]))CF_itera($2)')

# Keywords act as untyped %token
m4_define(CF_keywd, `m4_ifdef([[CF_tok_$1]],,[[m4_define([[CF_tok_$1]],1)m4_define([[CF_toks]],CF_toks $1)]])')
m4_define(CF_KEYWORDS, `m4_define([[CF_toks]],[[]])CF_iterate([[CF_keywd]], [[$@]])m4_ifelse(CF_toks,,,%token[[]]CF_toks
)DNL')

# Dynamic syntax rules
m4_define(CF_dyn_rules,)
m4_define(CF_ADDTO, `m4_define([[CF_rule_$1]],m4_ifdef([[CF_rule_$1]],CF_rule_$1 | ,[[m4_define([[CF_dyn_rules]],CF_dyn_rules[[CF_RULE($1)
]])]])$2)DNL')

42 43 44 45
# CLI commands
m4_define(CF_CLI, `m4_define([[CF_cmd]], cmd_[[]]m4_translit($1, [[ ]], _))DNL
m4_divert(2)CF_KEYWORDS(m4_translit($1, [[ ]], [[,]]))
m4_divert(3)CF_ADDTO(cli_cmd, CF_cmd)
46
CF_cmd: $1 $2 END')
47
m4_define(CF_CLI_CMD, `')
48
m4_define(CF_CLI_HELP, `')
49

Martin Mareš's avatar
Martin Mareš committed
50 51 52
# ENUM declarations are ignored
m4_define(CF_ENUM, `')

53 54 55 56 57 58 59 60 61 62 63 64 65 66
# After all configuration templates end, we finally generate the grammar file.
m4_m4wrap(`
m4_divert(0)DNL
%{
m4_undivert(1)DNL
%}

m4_undivert(2)DNL

%%
m4_undivert(3)DNL

/* Dynamic rules */

67
m4_define(CF_RULE, [[$1: CF_rule_$1 ;]])
68 69 70 71 72 73 74 75
CF_dyn_rules
%%
m4_undivert(4)DNL
')

# As we are processing C source, we must access all M4 primitives via
# m4_* and also set different quoting convention: `[[' and ']]'
m4_changequote([[,]])