configure.ac 11.3 KB
Newer Older
1 2
dnl ** This is a configure script template for BIRD
dnl ** Process it with autoconf to get ./configure
3
dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
4

5 6
AC_INIT
AC_CONFIG_SRCDIR([conf/confbase.Y])
7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32
AC_CONFIG_AUX_DIR([tools])

AC_ARG_ENABLE([client],
  [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  [],
  [enable_client=yes]
)

AC_ARG_ENABLE([debug],
  [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  [],
  [enable_debug=no]
)

AC_ARG_ENABLE([memcheck],
  [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  [],
  [enable_memcheck=yes]
)

AC_ARG_ENABLE([pthreads],
  [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  [],
  [enable_pthreads=try]
)

33 34 35 36 37 38
AC_ARG_ENABLE([libssh],
  [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
  [],
  [enable_libssh=try]
)

39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60
AC_ARG_WITH([protocols],
  [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  [],
  [with_protocols="all"]
)

AC_ARG_WITH([sysconfig],
  [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])],
  []
)

AC_ARG_WITH([runtimedir],
  [AS_HELP_STRING([--with-runtimedir=PATH], [path for runtime files @<:@LOCALSTATEDIR/run@:>@])],
  [runtimedir="$with_runtimedir"],
  [runtimedir="\$(localstatedir)/run"]
)

AC_ARG_WITH([iproutedir],
  [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  [given_iproutedir="yes"]
)

61 62 63 64
AC_ARG_VAR([FLEX], [location of the Flex program])
AC_ARG_VAR([BISON], [location of the Bison program])
AC_ARG_VAR([M4], [location of the M4 program])

65

66
if test "$srcdir" = . ; then
67 68
  # Building in current directory => create obj directory holding all objects
  objdir=obj
69
else
70 71
  # Building in separate directory
  objdir=.
72
fi
73 74 75

exedir=.

76 77
AC_SUBST([objdir])
AC_SUBST([exedir])
78
AC_SUBST([srcdir])
79
AC_SUBST([runtimedir])
80

81 82

if test "$enable_debug" = yes ; then
83 84
  CONFIG_FILE="bird.conf"
  CONTROL_SOCKET="bird.ctl"
85
else
86 87
  CONFIG_FILE="\$(sysconfdir)/bird.conf"
  CONTROL_SOCKET="$runtimedir/bird.ctl"
88
fi
89 90
AC_SUBST([CONFIG_FILE])
AC_SUBST([CONTROL_SOCKET])
91

92 93 94 95
AC_SEARCH_LIBS([clock_gettime], [rt posix4],
  [],
  [AC_MSG_ERROR([Function clock_gettime not available.])]
)
96

97
AC_CANONICAL_HOST
98

99
# Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
100
if test "$ac_test_CFLAGS" != set ; then
101
  bird_cflags_default=yes
102 103
fi

104
AC_PROG_CC
105
AC_PROG_CC_C99
106
if test -z "$GCC" ; then
107
  AC_MSG_ERROR([This program requires the GNU C Compiler.])
108 109
fi

110
if test "$enable_pthreads" != no ; then
111 112 113 114 115 116 117 118 119 120 121 122 123 124
  BIRD_CHECK_PTHREADS

  if test "$bird_cv_lib_pthreads" = yes ; then
    AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
    CFLAGS="$CFLAGS -pthread"
    LDFLAGS="$LDFLAGS -pthread"
    proto_bfd=bfd
  elif test "$enable_pthreads" = yes ; then
    AC_MSG_ERROR([POSIX threads not available.])
  fi

  if test "$enable_pthreads" = try ; then
    enable_pthreads="$bird_cv_lib_pthreads"
  fi
125 126
fi

127
if test "$bird_cflags_default" = yes ; then
128 129 130 131 132 133 134 135 136 137
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])

  CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
138
fi
139
AC_MSG_CHECKING([CFLAGS])
140
AC_MSG_RESULT([$CFLAGS])
141 142


143 144 145
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_RANLIB
146 147 148
AC_CHECK_PROG([FLEX], [flex], [flex])
AC_CHECK_PROG([BISON], [bison], [bison])
AC_CHECK_PROGS([M4], [gm4 m4])
149 150 151 152

test -z "$FLEX"	 && AC_MSG_ERROR([Flex is missing.])
test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
test -z "$M4"	 && AC_MSG_ERROR([M4 is missing.])
153 154 155 156 157

BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
  [],
  [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
)
158

159
if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
160 161 162 163 164 165 166 167
  if test -f $with_sysconfig ; then
    sysdesc=$with_sysconfig
  else
    sysdesc=$srcdir/sysdep/cf/$with_sysconfig
    if ! test -f $sysdesc ; then
      sysdesc=$sysdesc.h
    fi
  fi
168
elif test -f sysconfig.h ; then
169
  sysdesc=sysconfig
170
else
171 172
  case "$host_os" in
    linux*)
173 174 175
      sysdesc=linux
      default_iproutedir="/etc/iproute2"
      ;;
176
    freebsd*)
177 178
      sysdesc=bsd
      ;;
179
    kfreebsd*)
180 181
      sysdesc=bsd
      ;;
182
    netbsd*)
183
      sysdesc=bsd
184 185
      CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
      LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
186
      ;;
187
    openbsd*)
188 189
      sysdesc=bsd
      ;;
190
    dragonfly*)
191 192 193 194 195
      sysdesc=bsd
      ;;
    *)
      AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
      ;;
196 197
    esac
    sysdesc=$srcdir/sysdep/cf/$sysdesc.h
198
fi
199
AC_MSG_CHECKING([which OS configuration should we use])
200
AC_MSG_RESULT([$sysdesc])
201
if ! test -f $sysdesc ; then
202
  AC_MSG_ERROR([The system configuration file is missing.])
203
fi
204
sysname=`echo $sysdesc | sed 's/\.h$//'`
205
AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
206 207

AC_MSG_CHECKING([system-dependent directories])
208
sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
209 210
AC_MSG_RESULT([$sysdep_dirs])
AC_SUBST([sysdep_dirs])
211

212 213 214 215 216 217 218
if test "$with_iproutedir" = no ; then with_iproutedir= ; fi

if test -n "$given_iproutedir"
then iproutedir=$with_iproutedir
else iproutedir=$default_iproutedir
fi

219
AC_SUBST([iproutedir])
220

221 222 223 224
DAEMON_LIBS=
AC_SUBST(DAEMON_LIBS)

if test "$enable_libssh" != no ; then
225 226
  AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
  AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
227 228 229 230 231 232 233 234 235 236 237 238 239

  if test "$fail" != yes ; then
    AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
    DAEMON_LIBS="-lssh $DAEMON_LIBS"
    proto_rpki=rpki
    enable_libssh=yes
  else
    if test "$enable_libssh" = yes ; then
      AC_MSG_ERROR([LibSSH not available.])
    else
      enable_libssh=no
    fi
  fi
240
fi
241

242
all_protocols="$proto_bfd babel bgp ospf pipe radv rip $proto_rpki static"
243

244 245 246
all_protocols=`echo $all_protocols | sed 's/ /,/g'`

if test "$with_protocols" = all ; then
247
  with_protocols="$all_protocols"
248 249
fi

250 251 252 253 254 255 256
AH_TEMPLATE([CONFIG_BABEL], 	[Babel protocol])
AH_TEMPLATE([CONFIG_BFD],	[BFD protocol])
AH_TEMPLATE([CONFIG_BGP],	[BGP protocol])
AH_TEMPLATE([CONFIG_OSPF],	[OSPF protocol])
AH_TEMPLATE([CONFIG_PIPE],	[Pipe protocol])
AH_TEMPLATE([CONFIG_RADV],	[RAdv protocol])
AH_TEMPLATE([CONFIG_RIP],	[RIP protocol])
257
AH_TEMPLATE([CONFIG_RPKI],	[RPKI protocol])
258 259
AH_TEMPLATE([CONFIG_STATIC],	[Static protocol])

260 261
AC_MSG_CHECKING([protocols])
protocols=`echo "$with_protocols" | sed 's/,/ /g'`
262
if test "$protocols" = no ; then protocols= ; fi
263
for a in $protocols ; do
264 265 266 267 268 269 270 271
  if ! test -f $srcdir/proto/$a/Makefile ; then
    AC_MSG_RESULT([failed])
    AC_MSG_ERROR([Requested protocol $a not found])
  fi
  AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
done
AC_MSG_RESULT([ok])
AC_SUBST([protocols])
272

273
case $sysdesc in
274
  */linux*)
275 276 277
    AC_CHECK_HEADER([linux/rtnetlink.h],
      [],
      [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
278 279 280 281 282
      [
	dnl Some older versions of Linux kernel headers require these includes
	#include <asm/types.h>
	#include <sys/socket.h>
      ]
283 284
    )
    ;;
285 286
esac

287
AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
288
AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
289

290 291 292 293
AC_CHECK_HEADERS([linux/lwtunnel.h],
  [AC_DEFINE([HAVE_LWTUNNEL], [1], [Define to 1 if you have the <linux/lwtunnel.h> header file.])],
  [],
  [] dnl Force new AC_CHECK_HEADER semantics
294 295 296 297 298 299 300
)

AC_CHECK_MEMBERS([struct rtvia.rtvia_family],
  [AC_DEFINE([HAVE_STRUCT_RTVIA], [1], [Define to 1 if you have rtvia structure.])],
  [],
  [#include <linux/rtnetlink.h>]
)
301

302 303 304 305 306
AC_C_BIGENDIAN(
  [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
  [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
  [AC_MSG_ERROR([Cannot determine CPU endianity.])]
)
307

308
if test "$enable_debug" = yes ; then
309
  AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
310 311 312 313 314 315 316
  LDFLAGS="$LDFLAGS -rdynamic"
  CFLAGS="$CFLAGS -O0 -ggdb -g3 -gdwarf-4"

  AC_CHECK_HEADER([execinfo.h],
    [
      AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
      AC_SEARCH_LIBS([backtrace], [execinfo],
317
	[],
318 319 320 321 322
	[AC_MSG_ERROR([Function backtrace not available.])]
      )
    ]
  )

323 324 325 326 327 328
  if test "$enable_memcheck" = yes ; then
    AC_CHECK_LIB([dmalloc], [dmalloc_debug])
    if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
      AC_CHECK_LIB([efence], [malloc])
    fi
  fi
329 330
fi

331
CLIENT=birdcl
332
CLIENT_LIBS=
333
if test "$enable_client" = yes ; then
334
  CLIENT="$CLIENT birdc"
335 336 337 338 339 340
  BASE_LIBS="$LIBS"
  LIBS=""

  AC_CHECK_HEADERS([curses.h],
    [],
    [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
341
    [AC_INCLUDES_DEFAULT]
342 343
  )

344 345 346 347 348 349 350 351
  AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
    [TINFO_LIBS="$LIBS"; LIBS=""],
    [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
  )

  AC_CHECK_HEADERS([readline/readline.h readline/history.h],
    [],
    [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
352
    [AC_INCLUDES_DEFAULT]
353 354 355 356 357 358 359 360
  )

  AC_SEARCH_LIBS([rl_callback_read_char], [readline],
    [READLINE_LIBS="$LIBS"; LIBS=""],
    [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
    [$TINFO_LIBS]
  )

361
  AC_SEARCH_LIBS([add_history], [history readline],
362
    [HISTORY_LIBS="$LIBS"; LIBS=""],
363 364
    [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
    [$TINFO_LIBS]
365 366 367 368 369
  )

  AC_CHECK_LIB([readline], [rl_crlf],
    [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
    [],
370
    [$TINFO_LIBS]
371 372 373 374 375
  )

  AC_CHECK_LIB([readline], [rl_ding],
    [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
    [],
376
    [$TINFO_LIBS]
377
  )
378 379

  LIBS="$BASE_LIBS"
380
  CLIENT_LIBS="$HISTORY_LIBS $READLINE_LIBS $TINFO_LIBS"
381
fi
382 383
AC_SUBST([CLIENT])
AC_SUBST([CLIENT_LIBS])
384

385
mkdir -p $objdir/sysdep
386
AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
387
AC_CONFIG_FILES([Makefile:Makefile.in])
388
AC_OUTPUT
389

390 391 392 393 394 395 396 397 398 399
AC_MSG_RESULT()
AC_MSG_RESULT([BIRD was configured with the following options:])
AC_MSG_RESULT([        Source directory:	$srcdir])
AC_MSG_RESULT([        Object directory:	$objdir])
AC_MSG_RESULT([        Iproute2 directory:	$iproutedir])
AC_MSG_RESULT([        System configuration:	$sysdesc])
AC_MSG_RESULT([        Debugging:		$enable_debug])
AC_MSG_RESULT([        POSIX threads:		$enable_pthreads])
AC_MSG_RESULT([        Routing protocols:	$protocols])
AC_MSG_RESULT([        Client:			$enable_client])
400

401
rm -f $objdir/.*-stamp