configure.ac 12.3 KB
Newer Older
1 2
dnl ** This is a configure script template for BIRD
dnl ** Process it with autoconf to get ./configure
3
dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
4

5 6
AC_INIT
AC_CONFIG_SRCDIR([conf/confbase.Y])
7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32
AC_CONFIG_AUX_DIR([tools])

AC_ARG_ENABLE([client],
  [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  [],
  [enable_client=yes]
)

AC_ARG_ENABLE([debug],
  [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  [],
  [enable_debug=no]
)

AC_ARG_ENABLE([memcheck],
  [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  [],
  [enable_memcheck=yes]
)

AC_ARG_ENABLE([pthreads],
  [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  [],
  [enable_pthreads=try]
)

33 34 35 36 37 38
AC_ARG_ENABLE([libssh],
  [AS_HELP_STRING([--enable-libssh], [enable LibSSH support together with RPKI @<:@try@:>@])],
  [],
  [enable_libssh=try]
)

39 40 41 42 43 44
AC_ARG_ENABLE([mpls-kernel],
  [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
  [],
  [enable_mpls_kernel=try]
)

45 46 47 48 49 50 51
AC_ARG_WITH([protocols],
  [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  [],
  [with_protocols="all"]
)

AC_ARG_WITH([sysconfig],
52
  [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])]
53 54 55
)

AC_ARG_WITH([runtimedir],
56
  [AS_HELP_STRING([--with-runtimedir=PATH], [run-state data, obsolete variant of --runstatedir])],
57
  [runstatedir="$with_runtimedir"]
58 59 60 61 62 63 64
)

AC_ARG_WITH([iproutedir],
  [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  [given_iproutedir="yes"]
)

65 66 67 68
AC_ARG_VAR([FLEX], [location of the Flex program])
AC_ARG_VAR([BISON], [location of the Bison program])
AC_ARG_VAR([M4], [location of the M4 program])

69

70
if test "$srcdir" = . ; then
71 72
  # Building in current directory => create obj directory holding all objects
  objdir=obj
73
else
74 75
  # Building in separate directory
  objdir=.
76
fi
77 78 79

exedir=.

80 81
AC_SUBST([objdir])
AC_SUBST([exedir])
82
AC_SUBST([srcdir])
83 84 85 86

# Workaround for older Autoconfs that do not define runstatedir
AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
AC_SUBST([runstatedir])
87

88
CONFIG_FILE="\$(sysconfdir)/bird.conf"
89
AC_SUBST([CONFIG_FILE])
90 91

CONTROL_SOCKET="\$(runstatedir)/bird.ctl"
92
AC_SUBST([CONTROL_SOCKET])
93

94 95 96 97
AC_SEARCH_LIBS([clock_gettime], [rt posix4],
  [],
  [AC_MSG_ERROR([Function clock_gettime not available.])]
)
98

99
AC_CANONICAL_HOST
100

101
# Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
102
if test "$ac_test_CFLAGS" != set ; then
103
  bird_cflags_default=yes
104 105
fi

106
AC_PROG_CC
107
AC_PROG_CC_C99
108
if test -z "$GCC" ; then
109
  AC_MSG_ERROR([This program requires the GNU C Compiler.])
110 111
fi

112
if test "$enable_pthreads" != no ; then
113 114 115 116 117 118 119 120 121 122 123 124 125 126
  BIRD_CHECK_PTHREADS

  if test "$bird_cv_lib_pthreads" = yes ; then
    AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
    CFLAGS="$CFLAGS -pthread"
    LDFLAGS="$LDFLAGS -pthread"
    proto_bfd=bfd
  elif test "$enable_pthreads" = yes ; then
    AC_MSG_ERROR([POSIX threads not available.])
  fi

  if test "$enable_pthreads" = try ; then
    enable_pthreads="$bird_cv_lib_pthreads"
  fi
127 128
fi

129
if test "$bird_cflags_default" = yes ; then
130 131 132 133 134 135 136 137 138 139
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])

  CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_aliasing], [-fno-strict-aliasing])
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_fno_strict_overflow], [-fno-strict-overflow])
140
fi
141
AC_MSG_CHECKING([CFLAGS])
142
AC_MSG_RESULT([$CFLAGS])
143 144


145 146 147
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_RANLIB
148 149 150
AC_CHECK_PROG([FLEX], [flex], [flex])
AC_CHECK_PROG([BISON], [bison], [bison])
AC_CHECK_PROGS([M4], [gm4 m4])
151 152 153 154

test -z "$FLEX"	 && AC_MSG_ERROR([Flex is missing.])
test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
test -z "$M4"	 && AC_MSG_ERROR([M4 is missing.])
155

156 157 158 159 160 161 162
AC_MSG_CHECKING([bison version])
BIRD_CHECK_BISON_VERSION(BISON_VERSION)
AC_MSG_RESULT([$BISON_VERSION])
if test "$bird_bison_synclines" = yes; then
  M4FLAGS="$M4FLAGS -s"
fi

163 164 165 166
if test "$bird_bison_enhanced_error" = yes; then
  BISONFLAGS="$BISONFLAGS -Dparse.lac=full -Dparse.error=verbose"
fi

167
AC_SUBST([M4FLAGS])
168
AC_SUBST([BISONFLAGS])
169

170 171 172 173
BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
  [],
  [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
)
174

175
if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
176 177 178 179 180 181 182 183
  if test -f $with_sysconfig ; then
    sysdesc=$with_sysconfig
  else
    sysdesc=$srcdir/sysdep/cf/$with_sysconfig
    if ! test -f $sysdesc ; then
      sysdesc=$sysdesc.h
    fi
  fi
184
elif test -f sysconfig.h ; then
185
  sysdesc=sysconfig
186
else
187 188
  case "$host_os" in
    linux*)
189 190 191
      sysdesc=linux
      default_iproutedir="/etc/iproute2"
      ;;
192
    freebsd*)
193
      sysdesc=bsd
194 195
      CPPFLAGS="$CPPFLAGS -I/usr/local/include"
      LDFLAGS="$LDFLAGS -L/usr/local/lib"
196
      ;;
197
    kfreebsd*)
198 199
      sysdesc=bsd
      ;;
200
    netbsd*)
201
      sysdesc=bsd
202 203
      CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
      LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
204
      ;;
205
    openbsd*)
206 207
      sysdesc=bsd
      ;;
208
    dragonfly*)
209 210 211 212 213
      sysdesc=bsd
      ;;
    *)
      AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
      ;;
214 215
    esac
    sysdesc=$srcdir/sysdep/cf/$sysdesc.h
216
fi
217
AC_MSG_CHECKING([which OS configuration should we use])
218
AC_MSG_RESULT([$sysdesc])
219
if ! test -f $sysdesc ; then
220
  AC_MSG_ERROR([The system configuration file is missing.])
221
fi
222
sysname=`echo $sysdesc | sed 's/\.h$//'`
223
AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
224 225

AC_MSG_CHECKING([system-dependent directories])
226
sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
227 228
AC_MSG_RESULT([$sysdep_dirs])
AC_SUBST([sysdep_dirs])
229

230 231 232 233 234 235 236
if test "$with_iproutedir" = no ; then with_iproutedir= ; fi

if test -n "$given_iproutedir"
then iproutedir=$with_iproutedir
else iproutedir=$default_iproutedir
fi

237
AC_SUBST([iproutedir])
238

239 240 241 242
DAEMON_LIBS=
AC_SUBST(DAEMON_LIBS)

if test "$enable_libssh" != no ; then
243 244
  AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
  AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
245 246 247 248 249 250 251 252 253 254 255 256 257

  if test "$fail" != yes ; then
    AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
    DAEMON_LIBS="-lssh $DAEMON_LIBS"
    proto_rpki=rpki
    enable_libssh=yes
  else
    if test "$enable_libssh" = yes ; then
      AC_MSG_ERROR([LibSSH not available.])
    else
      enable_libssh=no
    fi
  fi
258
fi
259

260 261 262 263 264 265 266 267 268 269 270 271 272 273
if test "$enable_mpls_kernel" != no ; then
  BIRD_CHECK_MPLS_KERNEL

  if test "$bird_cv_mpls_kernel" = yes ; then
    AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
  elif test "$enable_mpls_kernel" = yes ; then
    AC_MSG_ERROR([Kernel MPLS support not found.])
  fi

  if test "$enable_mpls_kernel" = try ; then
    enable_mpls_kernel="$bird_cv_mpls_kernel"
  fi
fi

274
all_protocols="$proto_bfd babel bgp mrt ospf perf pipe radv rip $proto_rpki static"
275

276 277 278
all_protocols=`echo $all_protocols | sed 's/ /,/g'`

if test "$with_protocols" = all ; then
279
  with_protocols="$all_protocols"
280 281
fi

282 283 284
AH_TEMPLATE([CONFIG_BABEL], 	[Babel protocol])
AH_TEMPLATE([CONFIG_BFD],	[BFD protocol])
AH_TEMPLATE([CONFIG_BGP],	[BGP protocol])
Ondřej Zajíček's avatar
Ondřej Zajíček committed
285
AH_TEMPLATE([CONFIG_MRT],	[MRT protocol])
286 287 288 289
AH_TEMPLATE([CONFIG_OSPF],	[OSPF protocol])
AH_TEMPLATE([CONFIG_PIPE],	[Pipe protocol])
AH_TEMPLATE([CONFIG_RADV],	[RAdv protocol])
AH_TEMPLATE([CONFIG_RIP],	[RIP protocol])
290
AH_TEMPLATE([CONFIG_RPKI],	[RPKI protocol])
291 292
AH_TEMPLATE([CONFIG_STATIC],	[Static protocol])

293 294
AC_MSG_CHECKING([protocols])
protocols=`echo "$with_protocols" | sed 's/,/ /g'`
295
if test "$protocols" = no ; then protocols= ; fi
296
for a in $protocols ; do
297 298 299 300 301 302 303 304
  if ! test -f $srcdir/proto/$a/Makefile ; then
    AC_MSG_RESULT([failed])
    AC_MSG_ERROR([Requested protocol $a not found])
  fi
  AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
done
AC_MSG_RESULT([ok])
AC_SUBST([protocols])
305

306
case $sysdesc in
307
  */linux*)
308 309 310
    AC_CHECK_HEADER([linux/rtnetlink.h],
      [],
      [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
311 312 313 314 315
      [
	dnl Some older versions of Linux kernel headers require these includes
	#include <asm/types.h>
	#include <sys/socket.h>
      ]
316 317
    )
    ;;
318 319
esac

320
AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
321
AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
322 323 324 325 326 327

AC_C_BIGENDIAN(
  [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
  [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
  [AC_MSG_ERROR([Cannot determine CPU endianity.])]
)
328

329 330 331 332 333 334 335 336 337 338 339 340 341 342
BIRD_CHECK_ANDROID_GLOB
if test "$bird_cv_lib_glob" = no ; then
  AC_MSG_ERROR([glob.h not found.])
elif test "$bird_cv_lib_glob" != yes ; then
  LIBS="$LIBS $bird_cv_lib_glob"
fi

BIRD_CHECK_ANDROID_LOG
if test "$bird_cv_lib_log" = no ; then
  AC_MSG_ERROR([don't know how to link syslog.])
elif test "$bird_cv_lib_log" != yes ; then
  LIBS="$LIBS $bird_cv_lib_log"
fi

343
if test "$enable_debug" = yes ; then
344
  AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
345
  LDFLAGS="$LDFLAGS -rdynamic"
346 347 348 349
  CFLAGS="$CFLAGS -O0 -ggdb -g3"

  BIRD_CHECK_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4], [])
  BIRD_ADD_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4])
350 351 352 353 354

  AC_CHECK_HEADER([execinfo.h],
    [
      AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
      AC_SEARCH_LIBS([backtrace], [execinfo],
355
	[],
356 357 358 359 360
	[AC_MSG_ERROR([Function backtrace not available.])]
      )
    ]
  )

361 362 363 364 365 366
  if test "$enable_memcheck" = yes ; then
    AC_CHECK_LIB([dmalloc], [dmalloc_debug])
    if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
      AC_CHECK_LIB([efence], [malloc])
    fi
  fi
367 368
fi

369
CLIENT=birdcl
370
CLIENT_LIBS=
371
if test "$enable_client" = yes ; then
372
  CLIENT="$CLIENT birdc"
373 374 375 376 377 378
  BASE_LIBS="$LIBS"
  LIBS=""

  AC_CHECK_HEADERS([curses.h],
    [],
    [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
379
    [AC_INCLUDES_DEFAULT]
380 381
  )

382 383 384 385 386 387 388 389
  AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
    [TINFO_LIBS="$LIBS"; LIBS=""],
    [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
  )

  AC_CHECK_HEADERS([readline/readline.h readline/history.h],
    [],
    [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
390
    [AC_INCLUDES_DEFAULT]
391 392 393 394 395 396 397 398
  )

  AC_SEARCH_LIBS([rl_callback_read_char], [readline],
    [READLINE_LIBS="$LIBS"; LIBS=""],
    [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
    [$TINFO_LIBS]
  )

399 400 401
  AC_CHECK_LIB([readline], [rl_crlf],
    [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
    [],
402
    [$TINFO_LIBS]
403 404 405 406 407
  )

  AC_CHECK_LIB([readline], [rl_ding],
    [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
    [],
408
    [$TINFO_LIBS]
409
  )
410 411

  LIBS="$BASE_LIBS"
412
  CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
413
fi
414 415
AC_SUBST([CLIENT])
AC_SUBST([CLIENT_LIBS])
416

417
mkdir -p $objdir/sysdep
418
AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
419
AC_CONFIG_FILES([Makefile:Makefile.in])
420
AC_OUTPUT
421

422 423 424 425 426 427 428 429 430
AC_MSG_RESULT()
AC_MSG_RESULT([BIRD was configured with the following options:])
AC_MSG_RESULT([        Source directory:	$srcdir])
AC_MSG_RESULT([        Object directory:	$objdir])
AC_MSG_RESULT([        Iproute2 directory:	$iproutedir])
AC_MSG_RESULT([        System configuration:	$sysdesc])
AC_MSG_RESULT([        Debugging:		$enable_debug])
AC_MSG_RESULT([        POSIX threads:		$enable_pthreads])
AC_MSG_RESULT([        Routing protocols:	$protocols])
431
AC_MSG_RESULT([        Kernel MPLS support:	$enable_mpls_kernel])
432
AC_MSG_RESULT([        Client:			$enable_client])
433

434
rm -f $objdir/.*-stamp