sanitizer.m4 2.39 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71
# Copyright 2015 CZ.NIC, z.s.p.o.
#
# This program is free software: you can redistribute it and/or modify it
# under the terms of the GNU General Public License version 3, as published
# by the Free Software Foundation.
#
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranties of
# MERCHANTABILITY, SATISFACTORY QUALITY, or FITNESS FOR A PARTICULAR
# PURPOSE.  See the GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License along
# with this program.  If not, see <http://www.gnu.org/licenses/>.

#
# Processes --with-sanitize= and --with-sanitize-coverage= flags, checks
# if the options are supported by the compiler, and sets the following
# variables accordingly:
#
# - sanitize_enabled          yes|no
# - sanitize_coverage_enabled yes|no
# - sanitize_CFLAGS           -fsanitize=... -fsanitize-coverage=...
#
AC_DEFUN([AX_SANITIZER], [

  # Configure options
  AC_ARG_WITH([sanitize],
    [AS_HELP_STRING([--with-sanitize], [Compile with sanitizer [default=no]])],
    [],
    [with_sanitize=no]
  )
  AC_ARG_WITH([sanitize-coverage],
    [AS_HELP_STRING([--with-sanitize-coverage], [Compile with sanitizer coverage [default=no]])],
    [],
    [with_sanitize_coverage=no]
  )

  # Default values
  AS_IF([test "$with_sanitize" = "yes"], [ with_sanitize=address ])
  AS_IF([test "$with_sanitize_coverage" = "yes"], [ with_sanitize_coverage=edge,indirect-calls,8bit-counters ])

  # Construct output variables
  sanitize_enabled=no
  sanitize_coverage_enabled=no
  AS_IF([test "$with_sanitize" != "no"], [
    sanitize_CFLAGS="-fsanitize=${with_sanitize}"
    sanitize_enabled=yes
    AS_IF([test "$with_sanitize_coverage" != "no"], [
      sanitize_CFLAGS="$sanitize_CFLAGS -fsanitize-coverage=${with_sanitize_coverage}"
      sanitize_coverage_enabled=yes
    ])
  ], [
    sanitize_CFLAGS=
    AS_IF([test "$with_sanitize_coverage" != "no"], [
      AC_MSG_WARN([--with-sanitize-coverage cannot be used without --with-sanitize])
    ])
  ])

  # Test compiler support
  save_CFLAGS="$CFLAGS"
  CFLAGS="$CFLAGS $sanitize_CFLAGS"
  AC_MSG_CHECKING([whether compiler accepts '${sanitize_CFLAGS}' options])
  AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
    AC_MSG_RESULT([yes])
  ], [
    AC_MSG_RESULT([no])
    AC_MSG_ERROR([Sanitizer options are not supported.])
  ])
  CFLAGS="$save_CFLAGS"

]) # AX_SANITIZER